请问这段汇编语言转成C语言如何写？单片机的

LCD_init:
CALL DELAY_10MS ;延时15MS
CALL DELAY_10MS
CALL DELAY_10MS
MOV A,#30H ;显示模式设置(不检测忙信号)
CALL LCD_write_cmd_N ;共三次
CALL DELAY_10MS
MOV A,#30H
CALL LCD_write_cmd_N
CALL DELAY_10MS
MOV A,#30H
CALL LCD_write_cmd
MOV A,#38H ;显示模式设置(以后均检测忙信号)
CALL LCD_write_cmd
MOV A,#08H ;显示关闭
CALL LCD_write_cmd
MOV A,#01H ;显示清屏
CALL LCD_write_cmd
MOV A,#00001100b ;显示光标移动设置
CALL LCD_write_cmd
MOV A,#00000110b ;显示开及光标设置
CALL LCD_write_cmd

RET
LCD_write_cmd: ;送控制字子程序(检测忙信号)
CALL WAITIDLE
LCD_write_cmd_N: ;送控制字子程序(不检测忙信号)
CLR LCD_RS ;RS=0 RW=0 E=高脉冲
CLR LCD_RW
MOV LCD_DATA,A
SETB LCD_E
NOP
CLR LCD_E
RET
LCD_write_data: ;写字符子程序
CALL WAITIDLE
SETB LCD_RS ;RS=1 RW=0 E=高脉冲
CLR LCD_RW
MOV LCD_DATA,A
SETB LCD_E
NOP
CLR LCD_E
RET
WAITIDLE:
PUSH ACC ;正常读写操作之前必须检测LCD控制器状态
MOV LCD_DATA,#0FFH
CLR LCD_RS ;RS=0 RW=1 E=高电平
SETB LCD_RW
SETB LCD_E
WTD_PA: NOP ;DB7: 0 LCD控制器空闲
JB LCD_BUSY,WTD_PA ; 1 LCD控制器忙
CLR LCD_E
POP ACC
RET
delay_10ms:
mov r7,#100
delay_10ms_l0:
mov r6,#100
delay_10ms_l1:
djnz r6,delay_10ms_l1
nop
djnz r7,delay_10ms_l0
ret

void LCD_init(void)
{
delay_10ms();
delay_10ms();
delay_10ms();
lcd_write_cmd_N(0x30);
delay_10ms();
lcd_write_cmd_N(0x30);
delay_10ms();
lcd_write_cmd(0x30);
lcd_write_cmd(0x38);
lcd_write_cmd(0x08);
lcd_write_cmd(0x01);
lcd_write_cmd(0x0c);
lcd_write_cmd(0x06);
}
void lcd_write_cmd(unsigned char cmd)
{
waitidle();
lcd_write_cmd_N(cmd);
}
void lcd_write_cmd_N(unsigned char cmd)
{
LCD_RS=0;
LCD_RW=0;
LCD_DATA=cmd;
LCD_E=1;
_nop_();
LCD_E=0;
}
void lcd_write_data(unsigned char dat)
{
waitidle();
LCD_RS=1;
LCD_RS=0
LCD_DATA=dat;
LCD_E=1;
_nop_();
LCD_E=0;
}
void waitidle(void)
{
LCD_DATA=0xff;
LCD_RS=0;
LCD_RW=1;
LCD_E=1;
while(LCD_BUSY)
{
_nop_();
}
LCD_E=0;
}
void delay_10ms(void)
{
unsigned char i,j;
for(i=0;i<15;i++)
for(j=0;j<125;j++);
}

温馨提示：内容为网友见解，仅供参考

当前网址：https://11.t2y.org/zz/svv4744mm.html