一个简单的编写汇编语言程序的问题~求高手帮忙

要求实现:从键盘中输入0—65535 之间的十进制数，将其转换成十六进制数，并在屏幕上显示出，当按下ESC键以后显示OK 并退出程序。

请高手帮忙编写下程序。谢谢。

; 本程序通过编译，运行正确
Code Segment
Assume CS:Code,DS:Code
CR equ 000DH
LF equ 000AH
KB_Back equ 0008H
KB_ESC equ 001BH
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出一个字符
; 入口：dl=要显示的字符
enter_Chr proc Near
push ax
mov ah,02h
int 21h
pop ax
ret
enter_Chr endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：显示指定地址（Str_Addr）的字符串
; 入口：
; Str_Addr＝字符串地址（要求在数据段）
; 用法: Output Str_Addr
; 用法举例：Output PromptStr
Output MACRO Str_Addr
lea dx,Str_Addr
mov ah,9
int 21h
EndM
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：取光标位置
; 入口：无
; 出口：DH=行号，DL=列号
GetCursor Proc Near
PUSH AX
PUSH BX
PUSH CX
XOR BX,BX
MOV AH,3
INT 10H
MOV Cursor_Row,DH
MOV Cursor_Col,DL
POP CX
POP BX
POP AX
RET
Cursor_Row DB ?
Cursor_Col DB ?
GetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：置光标位置
; 入口：Cursor_Row=行坐标; Cursor_Col: 列坐标)
SetCursor Proc Near
PUSH CX
PUSH BX
PUSH AX
MOV DH,Cursor_Row
MOV DL,Cursor_Col
XOR BX,BX
MOV AH,2
INT 10H
POP AX
POP BX
POP CX
RET
SetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出回车换行
enter_CTLF proc Near
push ax
push dx
mov ah,02h
mov dl,0dh
int 21h
mov dl,0ah
int 21h
pop dx
pop ax
ret
enter_CTLF endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：键盘输入一个N位的十进制数字，
; 用逻辑和移位指令将其转换成二进制数并保存在指定的内存单元。
; 入口：N=数字位数；di=保存输入的数字首地址
; 出口：转换后的二进制数保存在di所指的单元
Input_Digit Proc Near
push dx
push cx
push bx
push di
lea di,@@Save_Tmp
push di
cld
mov cx,N
push cx
@@Input: call GetCursor ;取光标位置
mov ah,1 ;从键盘接受一个字符
int 21h
cmp al,KB_ESC
jnz $+12
mov Mark_Bit,al
pop cx
pop di
pop di
pop bx
pop cx
pop dx
ret
cmp al,CR ;若键入的是回车，已经键入的数字不足N位
jz @@ASC_Dec ;转去处理已经键入的数字
cmp al,KB_Back
jz @@KBBack ;若是回空键，重新输入
cmp al,'0'
jb @@KB_Back ;若低于数字'0'，重新输入
cmp al,'9'
ja @@KB_Back ;若低于数字'9'，重新输入
jmp @@Save_Dig
@@KBBack: dec Cursor_Col
inc cx
dec di
@@KB_Back: call SetCursor ;置光标位置
jmp @@Input
@@Save_Dig: and al,0fh ;转换成二进制数
stosb ;保存
loop @@Input ;接受下一个数字
@@ASC_Dec: mov ax,cx
pop cx
pop si
sub cx,ax ;实际输入的数字位数
xor dx,dx
xor ax,ax
jcxz @@Save_Ret ;若直接回车，没有输入任何数字，按输入'0'处理
dec cx ;实际输入的数字位数减1，准备把输入的这一串数字转换成二进制数
mov bx,10
@@Mul_Ten: lodsb
cbw
add ax,dx
mul bx
mov dx,ax
loop @@Mul_Ten
lodsb
cbw
add ax,dx
@@Save_Ret: pop di
stosw
pop bx
pop cx
pop dx
mov Mark_Bit,0
ret
@@Save_Tmp db 16 dup(?)
Input_Digit EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：将AL中的低4位二进制数转换成十六进制显示的ASCII码
; 入口：AL
; 出口：AL=转换后的ASCII码
AL_ASCII Proc Near
cmp al,10 ;AL<10?
jb @@To_ASCII ;AL<10，按数字处理
add al,7 ;AL>=10，按大写字母处理
@@To_ASCII: add al,'0' ;转换成相应的数字或大写字母
ret
AL_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：将AL中的字节数转换成十六进制显示的ASCII码
; 入口：AL
; 出口：AX=转换后的ASCII码
Byte_ASCII Proc Near
push cx
mov cx,4
xor ah,ah ;将AH置0
shl ax,cl ;将AX左移4位
shr al,cl ;将AL右移4位
xchg ah,al
call AL_ASCII ;调用子程序，将AL中的值转换成相应的ASCII码
xchg ah,al
call AL_ASCII
xchg ah,al
pop cx
ret
Byte_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
N equ 5 ;数字位数
Number dw ? ;16位二进制数
PromptStr DB 'Please input a decimal(0---65535, ESC to exit): $'
Hex_String db 'The heximal: '
Hex_Str db ' H$'
Mark_Bit db ? ;标志字节
Disp_Ok db 'OK$'
Start: push cs
pop ds
push cs
pop es ;使数据段、附加段与代码段同段
Input_Dec: Output PromptStr ;提示输入十进制数
lea di,Number ;分数存放地址
call Input_Digit ;从键盘输入一个十进制数
cmp Mark_Bit,KB_ESC
je Exit_Proc
call enter_CTLF ;输出一个回车、换行
call enter_CTLF ;输出一个回车、换行
lea di,Hex_Str
mov ax,Number ;读出这个数
push ax
xchg ah,al ;先转换高位字节
call Byte_ASCII ;把8位二进制数转换成十六进制显示的ASCII码
stosw ;保存至字符串变量
pop ax
call Byte_ASCII ;把8位二进制数转换成十六进制显示的ASCII码
stosw
Output Hex_String ;显示十六进制数
call enter_CTLF ;输出一个回车、换行
call enter_CTLF ;输出一个回车、换行
jmp Input_Dec
Exit_Proc: call SetCursor ;置光标位置
Output Disp_Ok
mov ah,4ch ;结束程序
int 21h
Code ENDS
END Start ;编译到此结束

温馨提示：内容为网友见解，仅供参考

当前网址：https://11.t2y.org/zz/m24pf2f8.html